home *** CD-ROM | disk | FTP | other *** search
/ TeX 1995 July / TeX CD-ROM July 1995 (Disc 1)(Walnut Creek)(1995).ISO / dviware / quicspool / wwfonts / ttextit.mf < prev   
Text File  |  1990-10-01  |  12KB  |  337 lines
  1. % $Header: ttextit.mf,v 1.1 88/01/15 13:15:30 simpson Rel $
  2. % $Log:    ttextit.mf,v $
  3. % Revision 1.1  88/01/15  13:15:30  simpson
  4. % initial release
  5. % 
  6. % Revision 0.2  88/01/14  10:12:30  simpson
  7. % fixed Rule and Underscore
  8. % 
  9. % Revision 0.1  88/01/07  08:15:20  simpson
  10. % beta test
  11. % 
  12. % The Computer Modern Text Italic family (by D. E. Knuth, 1979--1985)
  13.  
  14. mode_setup; font_setup;
  15.  
  16. input itall;  % lower case (minuscules)
  17. if ligs>1: font_coding_scheme:="Troff text";
  18.  input titalig;  % letter ligatures
  19. else: font_coding_scheme:=if ligs=0: "TeX typewriter text"
  20.   else: "TeX text without f-ligatures" fi;
  21.  spanish_shriek=oct"016"; spanish_query=oct"017"; fi
  22. minus=oct"004"; vertical=oct"174";
  23.  
  24. font_slant slant; font_x_height x_height#;
  25. if monospace: font_normal_space 9u#; % no stretching or shrinking
  26.  font_quad 18u#;
  27.  font_extra_space 9u#;
  28.  letter_fit#:=letter_fit:=0;
  29. else: font_normal_space 6u#+2letter_fit#;
  30.  font_normal_stretch 3u#; font_normal_shrink 2u#;
  31.  font_quad 18u#+4letter_fit#;
  32.  font_extra_space 2u#; fi
  33.  
  34. % We need to create space characters with no bitmap for \| and \^.  I put
  35. % them in oct"000" and oct"177" since these characters are not normally
  36. % used by ditroff.
  37. % My own creation (...creation being a generous term), for \|, 1/6 em
  38. beginchar(oct"000", 16/6u#, 0, 0);
  39. endchar;
  40.  
  41. % My own creation, for \^, 1/12 em
  42. beginchar(oct"177", 16/12u#, 0, 0);
  43. endchar;
  44.  
  45. % From the font lasy10.mf, file lasy.mf
  46. cmchar "Box";
  47. beginchar(oct"024",2.1math_axis#+4u#,v_center(7u#));
  48. italcorr math_axis#*slant;
  49. adjust_fit(0,0); pickup rule.nib;
  50. numeric a; a=round(2.1math_axis);
  51. x1=x4=good.x 2u; x2=x3=x1+a;
  52. y3=y4=.5(cap_height-a); y1=y2=y3+a;
  53. draw z1--z2--z3--z4--cycle;
  54. labels(1,2,3,4); endchar;
  55.  
  56. % Stolen from font cmsy10, file symbol.mf
  57. cmchar "Open bullet";
  58. beginchar(oct"025",9u#,v_center(7u#));
  59. adjust_fit(0,0); pickup rule.nib; autorounded;
  60. lft x6=hround u; x2=w-x6; top y8=h; y2=math_axis;
  61. circle_points; draw_circle;  % circle
  62. labels(1,2,3,4,5,6,7,8); endchar;
  63.  
  64. % Stolen from the font cmr10, file accent.mf
  65. cmchar "Umlaut (double dot) accent";
  66. numeric dot_diam#,dot_diam;
  67. dot_diam#=max(dot_size#,cap_curve#);
  68. beginchar(oct"026",9u#,min(asc_height#,10/7x_height#+.5dot_diam#),0);
  69. dot_diam=max(tiny.breadth,hround(max(dot_size,cap_curve)-2stem_corr));
  70. italcorr h#*slant+.5dot_diam#-2.25u#;
  71. adjust_fit(0,0);
  72. pickup tiny.nib; pos1(dot_diam,0); pos2(dot_diam,90);
  73. x1=x2=2.75u; top y2r=h+1;
  74. if bot y2l<x_height+o+slab: y2l:=min(y2r-eps,x_height+o+slab+.5tiny); fi
  75. y1=.5[y2l,y2r]; dot(1,2);  % left dot
  76. pos3(dot_diam,0); penpos4(y2r-y2l,90); y3=y4=y1; x3=x4=w-x1;
  77. dot(3,4);  % right dot
  78. penlabels(1,2,3,4); endchar;
  79.  
  80. % Stolen from the font cmr10.mf, file accent.mf
  81. cmchar "Cedilla accent";
  82. beginchar(oct"027",8u#,0,.875desc_depth#);
  83. adjust_fit(0,0);
  84. x1=.5w+.5u;
  85. if serifs: pickup crisp.nib; pos1(stem,0); pos2(stem,0);
  86.  pos3(vair,90); pos4(stem,0); pos5(vair,-90);
  87.  x1=x2; z3l=z2l; x4=x2+1.5u; x5=x3-1.5u;
  88.  bot y1=-o; bot y2=-vround 2/7d-o; y4=.5[y3,y5]; bot y5=-d-o;
  89.  filldraw stroke z1e--z2e;  % stem
  90.  filldraw stroke z3e{right}...z4e{down}...{left}z5e;  % hook
  91. else: pickup fine.nib; pos1(vair,0); top y1=-o-2;
  92.  pos2(.5[vair,stem],0); bot y2=-d-o; x2=x1-1.25u;
  93.  filldraw stroke z1e--z2e; fi  % diagonal
  94. penlabels(1,2,3,4,5); endchar;
  95.  
  96. % My own creation, a zero width period.  Used for dots in pic(1).
  97. cmchar "Dot for pic boxes";
  98. numeric dot_diam#; dot_diam#=if monospace: 5/4 fi\\ dot_size#;
  99. define_whole_blacker_pixels(dot_diam);
  100. beginchar(oct"030",0,dot_diam#,0);
  101. period_width#:=5u#; define_pixels(period_width);
  102. pickup fine.nib;
  103. pos1(dot_diam,0); pos2(dot_diam,90);
  104. lft x1l=hround(.5period_width-.5dot_diam); bot y2l=0; z1=z2; dot(1,2);  % dot
  105. penlabels(1,2); endchar;
  106.  
  107. % My own creation.  The fractions look like hell.
  108. cmchar "1/4 symbol";
  109. beginchar(oct"021", 12u#, body_height#, paren_depth#);
  110. italcorr body_height#*slant-.5u#;
  111. adjust_fit(0,0); pickup rule.nib;
  112. rt x1=hround(w-u)+eps; top y1=h+eps;
  113. lft x2=hround u-eps; bot y2=-d-eps;
  114. draw z1--z2;  % diagonal
  115. x3=x4=1/4w; y3=38/40h; y4=23/40h; 
  116. draw z3--z4;  % number 1
  117. x5=x6=32/40w; y7=y8=1/8h; y5=-.2d; y6=.37h; x7=26/40w; x8=.85w;
  118. draw z5--z6--z7--z8;
  119. endchar;
  120.  
  121. % My own creation
  122. cmchar "1/2 symbol";
  123. beginchar(oct"022", 12u#, body_height#, paren_depth#);
  124. italcorr body_height#*slant-.5u#;
  125. adjust_fit(0,0); pickup rule.nib;
  126. rt x1=hround(w-u)+eps; top y1=h+eps;
  127. lft x2=hround u-eps; bot y2=-d-eps;
  128. draw z1--z2;  % diagonal
  129. x3=x4=1/4w; y3=38/40h; y4=23/40h; 
  130. draw z3--z4;  % number 1
  131. x5=x9=.65w; x10=x7=.85w; x6=.74w;
  132. y9=y10=-.2d; y6=.37h; y5=.32h; y7=.30h;
  133. draw z5{dir 45}..z6..z7{dir -90}..{dir 225}z9; % number 2
  134. draw z9--z10;
  135. endchar;
  136.  
  137. % My own creation.
  138. cmchar "3/4 symbol";
  139. beginchar(oct"023", 12u#, body_height#, paren_depth#);
  140. italcorr body_height#*slant-.5u#;
  141. adjust_fit(0,0); pickup rule.nib;
  142. rt x1=hround(w-u)+eps; top y1=h+eps;
  143. lft x2=hround u-eps; bot y2=-d-eps;
  144. draw z1--z2;  % diagonal
  145. draw (quartercircle rotated -90 & halfcircle) scaled .1875h shifted 
  146. (.25w,.8562h); % number 3
  147. draw (halfcircle rotated -180 & quartercircle) scaled .1875h shifted 
  148. (.25w,.6687h);
  149. x5=x6=32/40w; y7=y8=1/8h; y5=-.2d; y6=.37h; x7=26/40w; x8=.85w;
  150. draw z5--z6--z7--z8;
  151. endchar;
  152.  
  153. % From the font cmsy10, file sym.mf
  154. iff known vertical: cmchar "Vertical line";
  155. beginchar(vertical,5u#,body_height#,paren_depth#);
  156. italcorr body_height#*slant+.5rule_thickness#-2u#;
  157. adjust_fit(0,0); pickup rule.nib;
  158. x1=x2=good.x .5w; top y1=h+eps; bot y2=-d-eps;
  159. draw z1--z2;  % stem
  160. labels(1,2); endchar;
  161.  
  162. % My own creation
  163. cmchar "Rule";
  164. beginchar(oct"005",12u#,x_height#,.7u#);
  165. italcorr .5x_height#*slant-.5u#;
  166. adjust_fit(0,0);
  167. numeric below_baseline; below_baseline#:=.2u#;
  168. define_pixels(below_baseline);
  169. define_blacker_pixels(thickness);
  170. pickup crisp.nib; pos1(vair,90); pos2(vair,90);
  171. top y1r=top y2r=vround(-below_baseline); rt x2=hround(w+6u#);
  172. lft x1=hround(0);
  173. filldraw stroke z1e--z2e;  % bar
  174. penlabels(1,2); endchar;
  175.  
  176. % My own creation
  177. cmchar "Underscore";
  178. beginchar("_",12u#,x_height#,.7u#);
  179. italcorr .5x_height#*slant-.5u#;
  180. adjust_fit(0,0);
  181. numeric below_baseline; below_baseline#:=.2u#;
  182. define_pixels(below_baseline);
  183. pickup crisp.nib; pos1(vair,90); pos2(vair,90);
  184. top y1r=top y2r=vround(-below_baseline); x2=hround(w);
  185. x1=hround 0;
  186. filldraw stroke z1e--z2e;  % bar
  187. penlabels(1,2); endchar;
  188.  
  189. % Hyphen from cmr10, file comlig.mf
  190. cmchar "Hyphen";
  191. beginchar("-",6u#,x_height#,0);
  192. italcorr .5x_height#*slant-.5u#;
  193. adjust_fit(0,0);
  194. numeric thickness; thickness=if hefty:bar else:.75[hair,stem] fi;
  195. pickup crisp.nib; pos1(thickness,90); pos2(thickness,90);
  196. top y1r=top y2r=vround(.5h+.5thickness); rt x2=hround(w-u)+eps;
  197. if monospace: x2=w-x1 else: lft x1=hround .2u-eps fi;
  198. filldraw stroke z1e--z2e;  % bar
  199. penlabels(1,2); endchar;
  200.  
  201. % My own creation
  202. cmchar "Cent sign";
  203. beginchar(oct"020",18u#,asc_height#,desc_depth#); autorounded;
  204. adjust_fit(if monospace:-3u#,-3u# else: 0,0 fi); pickup rule.nib;
  205. lft x6=hround u; x2=w-x6; top y8=h+o; bot y4=-d-o;
  206. circle_points; 
  207. x9=x11=.65[x6,x4]; x10=x12=.35[x4,x2]; 
  208. y9=y10=.35[y6,y8]; y11=y12=.65[y4,y6];
  209. x13=x14=.5[x6,x2]-.3u; y13=y4+2u; y14=y8-2u;
  210. draw z10..z9..z11..z12; draw z13--z14;
  211. labels(1,2,3,4,5,6,7,8,9,10,11,12,13,14); endchar;
  212.  
  213. % My own creation
  214. cmchar "Copyright";
  215. beginchar(oct"016",18u#,asc_height#,desc_depth#); autorounded;
  216. adjust_fit(if monospace:-3u#,-3u# else: 0,0 fi); pickup rule.nib;
  217. lft x6=hround u; x2=w-x6; top y8=h+o; bot y4=-d-o;
  218. circle_points; draw_circle;  % circle
  219. x9=x11=.65[x6,x4]; x10=x12=.35[x4,x2]; 
  220. y9=y10=.35[y6,y8]; y11=y12=.65[y4,y6];
  221. draw z10..z9..z11..z12;
  222. labels(1,2,3,4,5,6,7,8,9,10,11,12); endchar;
  223.  
  224. % My own creation
  225. cmchar "Registered";
  226. beginchar(oct"017",18u#,asc_height#,desc_depth#); autorounded;
  227. adjust_fit(if monospace:-3u#,-3u# else: 0,0 fi); pickup rule.nib;
  228. lft x6=hround u; x2=w-x6; top y8=h+o; bot y4=-d-o;
  229. circle_points; draw_circle;  % circle
  230. x9=x11=x12=.7[x6,x8]; x10=x13=.3[x4,x2]; 
  231. y12=y13=.5[y4,y6]; y9=.5[y6,y8]; y11=.5[y12,y9]; y10=.5[y11,y9];
  232. x14=.08[x4,x2]; y14=y9; 
  233. path p;
  234. p=z9--z14{dir 0}..z10..{dir 180}z11;
  235. z15=point 2.6 of p;
  236. draw z12--z9; draw z13--z15; draw p;
  237. labels(1,2,3,4,5,6,7,8,9,10,11,12,13,14,15); endchar;
  238.  
  239. % Stolen from the font cmr10, file accent.mf (actually the acute accent)
  240. cmchar "Footmark";
  241. beginchar(oct"015",9u#,min(asc_height#,2x_height#),0);
  242. italcorr h#*slant-if serifs: 1.5 fi u#;
  243. adjust_fit(0,0);
  244. if serifs: pickup crisp.nib; x1+.5stem=hround(w-2u); x2=2/3[x1,w-x1];
  245.  y1+.5stem=h+eps; y2=max(2/3[h,x_height],x_height+o+hair);
  246.  numeric theta; theta=angle(z2-z1)+90;
  247.  pos1(stem,theta); pos2(hair,theta);
  248.  filldraw circ_stroke z1e--z2e;  % diagonal
  249. else: pickup fine.nib; pos1(stem,0); pos2(vair,0);
  250.  rt x1r=hround(w-1.5u); lft x2l=hround(.5w-.25u-.5vair);
  251.  top y1=h; bot y2=vround 2/3[h,x_height];
  252.  filldraw stroke z1e--z2e; fi  % diagonal
  253. penlabels(1,2); endchar;
  254.  
  255. % Stolen from the font cmsy10, file symbol.mf
  256. cmchar "Dagger mark";
  257. beginchar(oct"014",8u#,asc_height#,desc_depth#);
  258. adjust_fit(0,0); pickup fine.nib;
  259. pos1(stem,0); pos2(thin_join,0); pos3(stem,0); pos4(hair,0);
  260. pos5(stem,90); pos2'(thin_join,90); pos6(stem,90); z2'=z2;
  261. x1=x2=x3=x4; x1-.5stem=hround(.5w-.5stem); w:=r:=2x1;
  262. x5-.5stem=hround u; x6=w-x5;
  263. y1+.5stem=h+oo; y2=y5=y6; y3=.57y2; bot y4=-d-o;
  264. y5+.5stem=floor(x_height+.5stem);
  265. filldraw circ_stroke z1e{down}..z2e{down}..z3e{down}..z4e;  % stem
  266. filldraw circ_stroke z5e{right}..{right}z2'e;  % left bulb
  267. filldraw circ_stroke z6e{left}..{left}z2'e;  % right bulb
  268. penlabels(1,2,3,4,5,6); endchar;
  269.  
  270. % Stolen from the font cmr10, file accent.mf (the Scandinavian circle accent)
  271. cmchar "Degree";
  272. beginchar(oct"013",13u#+4/3(asc_height#-x_height#)*slant,asc_height#,0);
  273. adjust_fit(cap_serif_fit#,cap_serif_fit#);
  274. numeric circ_hair,circ_vair;
  275. circ_hair=hround min(hair,u+.5); circ_vair=vround min(vair,(h-x_height)/6+.5);
  276. penpos1(circ_vair,90); penpos3(circ_vair,-90);
  277. penpos2(circ_hair,180); penpos4(circ_hair,0);
  278. x2r=hround(.5w-1.5u-.5circ_hair);
  279. x4r=w-x2r; x1=x3=.5w; y1r=h+apex_o; y2=y4=.5[y1,y3];
  280. y3r=vround(1/3[x_height,h]+apex_o);
  281. penstroke pulled_arc.e(1,2) & pulled_arc.e(2,3)
  282.  & pulled_arc.e(3,4) & pulled_arc.e(4,1) & cycle;  % bowl
  283. penlabels(1,2,3,4); endchar;
  284.  
  285. % My own creation
  286. cmchar "Square";
  287. beginchar(oct"010",9u#,v_center(7u#));
  288. italcorr math_axis#*slant;
  289. adjust_fit(0,0); pickup rule.nib;
  290. draw unitsquare scaled 7u shifted (.5w-7u/2,math_axis-7u/2);
  291. endchar;
  292.  
  293. % Stolen from the font cmsy10, file symbol.mf
  294. cmchar "Bullet";
  295. beginchar(oct"007",9u#,v_center(7u#));
  296. adjust_fit(0,0); pickup rule.nib; autorounded;
  297. lft x6=hround u; x2=w-x6; top y8=h; y2=math_axis; circle_points;
  298. filldraw z8{right}...z1{z2-z8}...z2{down}...z3{z4-z2}...z4{left}
  299.   ...z5{z6-z4}...z6{up}...z7{z8-z6}...cycle;  % circle and interior
  300. labels(1,2,3,4,5,6,7,8); endchar;
  301.  
  302. % Stolen from the font cmsy10, file sym.mf
  303. iff known minus: cmchar "Minus sign";
  304. beginarithchar(minus); pickup rule.nib;
  305. lft x1=hround 1.5u-eps; x2=w-x1; y1=y2=math_axis;
  306. draw z1--z2;  % bar
  307. labels(1,2); endchar;
  308.  
  309. input romanu;  % upper case (majuscules)
  310. input itald;  % numerals
  311. input titalp;  % ampersand, question marks, currency sign
  312. input tpunct;  % punctuation symbols common to roman and italic text
  313. if ligs>0: input tcomlig; fi  % ligatures common with roman text
  314. if ligs<=1: input romsub; fi  % substitutes for ligatures
  315.  
  316. if not monospace:
  317.  k#:=-.5u#; kk#:=-1.5u#; kkk#:=-2u#; % three degrees of kerning
  318.  ligtable "d": "w": "l": "l" kern +u#;
  319.  ligtable "F": "V": "o" kern kk#, "e" kern kk#,
  320.    "u" kern kk#, "r" kern kk#, "a" kern kk#, "A" kern kkk#,
  321.   "K": "X": "O" kern k#, "C" kern k#, "G" kern k#, "Q" kern k#;
  322.  ligtable "T": "y" kern kk#,
  323.   "Y": "e" kern kk#, "o" kern kk#, "r" kern kk#, "a" kern kk#, "u" kern kk#,
  324.   "P": "W": "A" kern kk#;
  325.  ligtable "O": "D": "X" kern k#, "W" kern k#, "A" kern k#,
  326.    "V" kern k#, "Y" kern k#;
  327.  ligtable "A": "R": "n" kern k#, "l" kern k#, "r" kern k#, "u" kern k#,
  328.    "m" kern k#, "t" kern k#, "i" kern k#, "C" kern k#, "O" kern k#, "G" kern k#,
  329.    "h" kern k#, "b" kern k#, "U" kern k#, "k" kern k#, "v" kern k#, "w" kern k#,
  330.    "Q" kern k#, "L": "T" kern kk#, "Y" kern kk#, "V" kern kkk#, "W" kern kkk#,
  331.   "b": "c": "e": "o": "p": "r": "e" kern -u#, "a" kern -u#, "o" kern -u#,
  332.    "d" kern -u#, "c" kern -u#, "g" kern -u#, "q" kern -u#;
  333.  fi
  334. % there are ligature/kern programs for |"f"| in the {\tt romlig} file
  335. % and for |"-"|, |"`"|, and |"'"| in the {\tt comlig} file
  336. bye.
  337.